* Tekrar korumas

$prot(repeat,#kanal-ad,nick,mesaj,satr,saniye)
Örnek: $prot(repeat,#ircforumlari,el33t,selam naber,2,5) bu identifier on TEXT eventi içinde kullandmzda 5 saniye içinde 2 kez selam naber yazsn tekrar edersem bu identifier $true olacaktr, yani öyle kullanabiliriz:

on @*:text:*:#:if $prot(repeat,#,$nick,$1-,2,5) { kick # $nick Tekrar etme! }



    * Flood korumas

$prot(flood,#kanal,nick,satr,saniye)

Örnek:

on @*:text:*:#:if $prot(flood,#,$nick,3,4) { kick # $nick Flood yapma }

Yukardaki kod 4 saniye içinde 3 satr yaz yazan kanaldan kickler.



    * Caps korumas

Belirlediiniz orandan fazla büyük harf kullananlar içindir
$prot(caps,mesaj,oran)

Örnek:

on @*:text:*:#:if $prot(caps,$1-,80) { kick # $nick Büyük harf kullanma! }

Yazd yaznn %80'inden fazlas büyük harf olan kii kanaldan atlr.



    * Uzun yaz korumas

$prot(long,mesaj,karakter says)

Örnek:

on @*:text:*:#:if $prot(long,$1-,150) { kick # $nick Uzun yaz yazma! }

150 karakterden fazla karakter içeren mesaj yazarsa kanaldan atlr



    * Kontrol kodu korumas

mIRC'de CTRL tularna basnca çkan kodlar içindir. (CTRL+K, CTRL+B, CTRL+U gibi)

Örnek:

on @*:text:*:#:if $prot(ctrlcode,$1-,15) { kick # $nick 15den fazla kontrol kodu kullanma! }

15'den fazla kontrol kodu kullanan kanaldan atlr.



    * Küfür korumas

$prot(bword,mesaj,dosya)

Örnek:

on @*:text:*:#:if $prot(bword,$1-,küfürler.txt) { kick # $nick Küfür etme! }

mIRC'de küfürler.txt dosyas oluturup alt alta wildcardda kullanarak istediin küfürleri eklediinde eer kiinin yazd yazda bunlardan biri varsa kanaldan atlr. Küfürler.txt dosyasna ekleme ekli öyle olmal:

*sex*
*fuck*
*anan?*

gibi..



    * Reklam korumas

$prot(spam,mesaj,dosya)
Ayn küfür korumas gibi çalr.

on @*:text:*:#:if $prot(spam,$1-,spam.txt) { kick # $nick Reklam yapma! }

spam.txt dosyasna wildcard kullanarak eklenen kelimeleri içeren mesaj yazan kanalan atlr.



    * Fazla Noktalama areti korumas

$prot(punc,mesaj,maksimum noktalama iareti says)
Belirlenen saydan fazla noktalama iaretlerini kullananlar kontrol etmek için identifiern punc özelliini kullanabilirsiniz. Noktalama iaretleri: ?!:;,.

on @*:text:*:#:if $prot(punc,$1-,20) { kick # $nick Bu kadar fazla noktalama iareti kullanma! }

Yukardaki örnekte op olduunuz kanalda 20'den fazla noktalama iareti kullananlar kanaldan atlr.

Ve ite kod: (Remote'a (ALT+R) koyuyoruz.)

alias prot {
if !$istok(repeat flood caps long ctrlcode bword spam punc,$1,32) { return $false }
goto $1
:repeat
var %÷ = $+(%,repeat.,$2,.,$3,.,$encode($4,m))
inc $(%÷,1)
if (!$timer($gettok(%÷,1,37))) { $+(.timer,$gettok(%÷,1,37)) 1 $6 unset $(%÷,1) }
if ($(%÷,2) >= $5) { unset $(%÷,1) | return $true }
else { return $false }
:flood
var %µ = $+(%,flood.,$2,.,$3)
inc $(%µ,1)
if (!$timer($gettok(%µ,1,37))) { $+(.timer,$gettok(%µ,1,37)) 1 $5 unset $(%µ,1) }
if ($(%µ,2) >= $4) { unset $(%µ,1) | return $true }
else { return $false }
:caps
var %e = $remove($strip($2),$chr(32))
return $iif($iif($len(%e) >= 10,$calc($regex(%e,/[A-ZÄÖÜÇ]/g)/$len(%e)*100),0) >= $3,$true,$false)
:long
return $iif($len($strip($2)) >= $3,$true,$false)
:ctrlcode
return $iif($regex($2,/[[:cntrl:]]/g) >= $3,$true,$false)
:bword
var %· = 1 | while $read($3,%·) { if $v1 iswm $2 { return $true } | inc %· } | return $false
:spam
var %º = 1 | while $read($3,%º) { if $v1 iswm $2 { return $true } | inc %º } | return $false
:punc
return $iif($regex($2,/([?!:;,\.])/g) >= $3,$true,$false)
}


Umarm iinize yarar, istediiniz gibi deitirip, kullanmakta özgürsünüz. steyen ben yazdm diyebilir.
NOT: imdilik aklma gelen korumalar bunlar, önerileriniz ve isteklerinizi belirtiniz.

Eer hepsini bir on TEXT eventi içinde kullanmak isterseniz bir örnek: (küfürler.txt ve reklamlar.txt'i oluturmay unutmayn.)

;Op olduum kanalda çalmas için
on @*:text:*:#:{
;Eer kanala yaz yazan nick op/voice/halfop deilse
if ($nick isreg #) {
;150 karakterden fazla karakter kullanan kicklenir
if $prot(long,$1-,150) { kick # $nick uzunyaz(>150) }
;15'den fazla kontrol kodu kullanan kicklenir
elseif $prot(ctrlcode,$1-,15) { kick # $nick controlcode(>15) }
;%80 oranndan fazla caps kullanan kicklenir
elseif $prot(caps,$1-,80) { kick # $nick caps(>%80) }
;5 saniye içinde 2 tekrar yapan kicklenir.
elseif $prot(repeat,#,$nick,$strip($1-),2,5) { kick # $nick tekrar(5sn:2) }
;1 saniye içinde 3 satr yazan kicklenir.
elseif $prot(flood,#,$nick,3,1) { kick # $nick flood(1sn:3) }
;küfürler.txt'den herhangi bir kelimeyi kullanan kicklenir
elseif $prot(bword,$1-,küfürler.txt) { kick # $nick küfür }
;reklamlar.txt'den herhangi bir kelime kullanan kicklenir
elseif $prot(spam,$1-,reklamlar.txt) { kick # $nick reklam }
;30'dan fazla noktalama iareti kullanan kicklenir
elseif $prot(punc,$1-,30) { kick # $nick noktalamaiareti(>30) }
}
}


Alntdr. (Anlatm el33t e aittir.)