Normal Mod | Çizgisel Mod

**Alience** · 07-29-2008, 08:08 PM

Addon/Ders: mIRC ve Excel
Yazar: Alience
Tarih: 28-07-2008
Açklama: mIRC ile Excel arasnda veri alverii yapmanza olanak salar
Versiyon: 1.0
-> mIRC denenen versiyon: 6,31
-> Office denenen versiyon: Xp
Not: çalmas için excel'in yüklü olmas gereklidir!

Adndan da anlalaca gibi com object kullanarak mIRC ile Excel arasnda veri aktarm yapmanza olanak salayacak addon,

batan belirtmek isterim görsel veya basit bireyler beklemeyin eer hala öyle bir hevesiniz var ise yaznn gerisini okumak

salnz açsndan zararl olabilir Tongue

.
Bu addonu yada kodlar deil türkçe dier dillerde dahi bulamazssnz. Baz kendini bilmezler benim baz çömezlerden kod

çaldm idda ediyor o kendini bilmezlere ramen bu kodu yaynlyorum en azndan faydalanan düzgün insanlara bir yardmmz

olsun.

Aadaki kodlar remoteye kopyalayn

Kod:

alias excel {

  if $com(excel) {

    var %i = $com(excel,Quit,3)

    .comclose excel

    if $com(sheet) { .comclose sheet }

    if $com(selsheet) { .comclose selsheet }

    if $com(workbook) { .comclose workbook }

    if $com(cells) { .comclose cells }

  }

  .comopen excel Excel.Application

  if ($comerr) {

    if $show && !$prop  { echo $color(info text) -a comopen failed }

    halt

  }

  ; make excel window visible

  if ($com(excel,Visible,5,i4,1) == 0) {

    if $show { echo $color(info text) -a $com failed }

  }

}

alias workbook {

  var %i = $com(excel,Workbooks,3,dispatch* workbook) 

  ;workbook ekliyoruz

  var %i = $iif($com(workbook,Add,3,dispatch* sheet),Workbook açld,$null)

  if $show && !$prop { echo $color(info text) -a %i }

}

alias sheets {

  if $com(selsheet) { .comclose selsheet }

  var %i = $iif($com(sheet,Sheets,3,uint,$1,dispatch* selsheet), Sheet $1,$null)

  if $show && !$prop { echo $color(info text) -a %i }

  if !$prop {

    if $2 != $null {

      var %i = $com(selsheet,$2,4,$iif($isnum($2),uint,bstr),$2-)

      return $com(selsheet).result

    }

  }

  else {

    if $prop {

      var %i = $com(selsheet,$prop,2)

      return $com(selsheet).result

    }    

  }

}

alias cells {

  if $com(cells) { .comclose cells }

  var %i = $com(selsheet,Cells,3,uint,$1,uint,$2,dispatch* cells)

  if $show && !$prop { echo $color(info text) -a  %i }

  if !$prop {

    if $3 != $null {

      var %i = $com(cells,$3,4,$iif($isnum($4),uint,bstr),$4-)

      return $com(cells).result

    }

  }

  else {

    if $prop {

      var %i = $com(cells,$prop,2)

      return $com(cells).result

    }    

  }

}

alias colls {

  if $com(colls) { .comclose colls }

  var %i = $com(selsheet,Columns,3,uint,$1,dispatch* colls)

  if $show && !$prop { echo $color(info text) -a  %i }

  if !$prop {

    if $3 != $null {

      var %i = $com(colls,$2,4,$iif($isnum($3),uint,bstr),$3-)

      return $com(colls).result

    }

  }

  else {

    if $prop {

      var %i = $com(colls,$prop,2)

      return $com(colls).result

    }    

  }

}

alias rows {

  if $com(rows) { .comclose rows }

  var %i = $com(selsheet,Rows,3,uint,$1,dispatch* rows)

  if $show && !$prop { echo $color(info text) -a  %i }

  if !$prop {

    if $3 != $null {

      var %i = $com(rows,$2,4,$iif($isnum($3),uint,bstr),$3-)

      return $com(rows).result

    }

  }

  else {

    if $prop {

      var %i = $com(rows,$prop,2)

      return $com(rows).result

    }    

  }

}

alias doldur {

  .excel

  .workbook

  .sheets 1

  var %i = 50

  while %i {

    .cells %i 1 value %i

    dec %i 1

  }

}

alias göster {

  var %i = 1

  while %i <= 50 {

    echo $color(info text) -a $cells(%i,1).value

    inc %i 1

  }

}

Kodda iki adet örnek mevcut /doldur komutunu girerseniz 1 den 50 ye kadar excel'e verileri yazar. /göster komutunu

girdiinizde ise bunlar mIRC de listeler.

Kod açklamalar:
kodlarn bana . (/.) koyarsanz hiçibir mesaj gözükmeyecektir (örn: /.sheets 2)

/excel ilk önce girmeniz gereken komuttur bo bir excel sayfas açar.
/workbook excel'i açtktan sonra kitap oluturmak için girmeniz gereken komuttur bu iki komut sras ile

uygulanmal ve excel ana penceresi dnda ilem yapacak iseniz ikisinide kesin yazmak zorundasnz!

/sheets
iki ekilde kullanabilirsiniz:
/sheets ve $sheets

bir çalma çalma sayfasn seçmek için:
/sheets 2 yazdnzda 2. çalma sayfasn seçer.

/sheets 2 activate yazdgnzda ise 2. çalma sayfasn aktif hale getirir.
komut hakknda denemelerimizi yapalm:
/excel
/workbook
/sheets 2 activate

sonuç olarak 2. sayfa aktif bir ekilde karnzda duruyor olmas gerek Big Grin

peki sheet'imizin adn almak ister isek ne yapmamz gerek:
//echo : $sheets(2).name

Bataki uyarmn sebebini yava yava anlamaya balyorsunuz ben size komple hazr kod vermiyorum sadece ana hatlarn

veriyorum bir koder arkadam üzerine eklentileri yazar ise çok basit kullanm olur fakat ben ana halini vermeyi ve

çkabilecek en fazla kullanm kod ile örneklemeyi (örn: //echo : $sheets(2).name) tercih ederim.

/cells
Sheets komutunda oldugu gibi cells komutunuda nomal komut ve identifier komutu olarak kullanabilirsiniz. Cells komutunu

kullanmak için sras ile:
1. excel açk olmal (mIRC balantl olmas için com tarafndan açlmal /excel)
2. içinde kitap açk olmal /workbook
3. seçili bir sayfa olmal /sheets

komutlar sras ile
/excel
/workbook
/sheets 1
/cells 1 1 value Deneme
;yukardaki komutun anlam 1. satr ve 1. sütun denk gelen hüçreyi Deneme ile doldur.
/cells 3 1 value Alience
;yukardaki komutun anlam 3. satr ve 1. sütun denk gelen hüçreyi Alience ile doldur'dur.

komutlar girdikten sonra;
//echo $cells(1,1).value
;yukardaki kodu yazdmzda Deneme deerini döner

//echo $cells(3,1).value
;Alience deerini döner

/colls
Kolon ilemleri için geçerli olan komuttur
/excel
/workbook
/sheets 1
;yukardaki komutlar excel com objesi açl deilse yazlacak

/colls 1 columnwidth 50
;1. kolonun geniliini 50 yapar

//echo : $colls(1).columnwidth
;1. kolonun geniliini döner

//echo : $colls(2).columnwidth
;2. kolonun geniliini döner

/rows
satr ilemleri için geçerli olan komuttur
/excel
/workbook
/sheets 1
;yukardaki komutlar excel com objesi açl deilse yazlacak

/rows 1 rowheight 50
;1. satr yüksekliini 50 yapar

//echo : $rows(1).rowheight
;1. satr yüksekliini döner

//echo : $rows(2).rowheight
;2. satr yüksekliini döner

gelelim daha ilginç komutlara
Tüm satrlar ayn yükseklikte yapmak:
//colls 2 rowheight 17,25
;yukardaki 2 2. kolon 1. veya 30. kolonda olabilirdi farketmiyor, 17,25 ise yükseklik

Tüm sütunlarn geniliini ayn yapmak:
//rows 2 columnwidth 17,25
;yukardaki kod gibi 2 2.kolon 17,25 genilik

1. Kolona Alience yazdrtmak:
//colls 1 value Alience

1. Satra Alience yazdrtmak:
//rows 1 value Alience

Kaytl bir excel(.xls) dosyas açtrmak:
//echo : $com(workbook,open,1,bstr,C:\dosya.xls)
;yukarda dosyamz c: dizininde

**Niyekine** · 07-29-2008, 09:30 PM

eline kolun Salk Aliance

**ByDeniS** · 07-30-2008, 06:21 PM

Ne söylemem gerekirki. Pro verim.

**ByDeniS** · 11-22-2008, 03:34 PM

Halim grafik aktartamazmyz Smile

chaart deil ama image Confused